16821490ce
* Fix issue#1874 Prior to this change, if user use one client connect emqx with mqtt v3.1.1, the client subscribe the topic and publish message to this topic, it would receive this message itself published, this commit provide a configure option to let user ignore the message itself published. This change fix issue 1874. * Small Fix * Fix bug * Better design * Fix compile warning and improve coverage * Better design to solve the performance issue * Fix typo * Fix typo * Delete spaces in end of lines. * Do not use anonymous function * Better performance
297 lines
12 KiB
Erlang
297 lines
12 KiB
Erlang
%% Copyright (c) 2018 EMQ Technologies Co., Ltd. All Rights Reserved.
|
|
%%
|
|
%% Licensed under the Apache License, Version 2.0 (the "License");
|
|
%% you may not use this file except in compliance with the License.
|
|
%% You may obtain a copy of the License at
|
|
%%
|
|
%% http://www.apache.org/licenses/LICENSE-2.0
|
|
%%
|
|
%% Unless required by applicable law or agreed to in writing, software
|
|
%% distributed under the License is distributed on an "AS IS" BASIS,
|
|
%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
%% See the License for the specific language governing permissions and
|
|
%% limitations under the License.
|
|
|
|
-module(emqx_client_SUITE).
|
|
|
|
-compile(export_all).
|
|
-compile(nowarn_export_all).
|
|
|
|
-import(lists, [nth/2]).
|
|
|
|
-include("emqx_mqtt.hrl").
|
|
|
|
-include_lib("eunit/include/eunit.hrl").
|
|
|
|
-include_lib("common_test/include/ct.hrl").
|
|
|
|
-define(TOPICS, [<<"TopicA">>, <<"TopicA/B">>, <<"Topic/C">>, <<"TopicA/C">>,
|
|
<<"/TopicA">>]).
|
|
|
|
-define(WILD_TOPICS, [<<"TopicA/+">>, <<"+/C">>, <<"#">>, <<"/#">>, <<"/+">>,
|
|
<<"+/+">>, <<"TopicA/#">>]).
|
|
|
|
all() ->
|
|
[ {group, mqttv4},
|
|
{group, mqttv5}
|
|
].
|
|
|
|
groups() ->
|
|
[{mqttv4, [non_parallel_tests],
|
|
[basic_test,
|
|
will_message_test,
|
|
offline_message_queueing_test,
|
|
overlapping_subscriptions_test,
|
|
%% keepalive_test,
|
|
redelivery_on_reconnect_test,
|
|
%% subscribe_failure_test,
|
|
dollar_topics_test]},
|
|
{mqttv5, [non_parallel_tests],
|
|
[request_response,
|
|
share_sub_request_topic]}
|
|
].
|
|
|
|
init_per_suite(Config) ->
|
|
emqx_ct_broker_helpers:run_setup_steps(),
|
|
Config.
|
|
|
|
end_per_suite(_Config) ->
|
|
emqx_ct_broker_helpers:run_teardown_steps().
|
|
|
|
request_response_exception(QoS) ->
|
|
{ok, Client} = emqx_client:start_link([{proto_ver, v5},
|
|
{properties, #{ 'Request-Response-Information' => 0 }}]),
|
|
{ok, _} = emqx_client:connect(Client),
|
|
?assertError(no_response_information,
|
|
emqx_client:sub_request_topic(Client, QoS, <<"request_topic">>)),
|
|
ok = emqx_client:disconnect(Client).
|
|
|
|
request_response_per_qos(QoS) ->
|
|
{ok, Requester} = emqx_client:start_link([{proto_ver, v5},
|
|
{client_id, <<"requester">>},
|
|
{properties, #{ 'Request-Response-Information' => 1}}]),
|
|
{ok, _} = emqx_client:connect(Requester),
|
|
{ok, Responser} = emqx_client:start_link([{proto_ver, v5},
|
|
{client_id, <<"responser">>},
|
|
{properties, #{
|
|
'Request-Response-Information' => 1}},
|
|
{request_handler,
|
|
fun(_Req) -> <<"ResponseTest">> end}
|
|
]),
|
|
{ok, _} = emqx_client:connect(Responser),
|
|
ok = emqx_client:sub_request_topic(Responser, QoS, <<"request_topic">>),
|
|
{ok, <<"ResponseTest">>} = emqx_client:request(Requester, <<"response_topic">>, <<"request_topic">>, <<"request_payload">>, QoS),
|
|
ok = emqx_client:set_request_handler(Responser, fun(<<"request_payload">>) ->
|
|
<<"ResponseFunctionTest">>;
|
|
(_) ->
|
|
<<"404">>
|
|
end),
|
|
{ok, <<"ResponseFunctionTest">>} = emqx_client:request(Requester, <<"response_topic">>, <<"request_topic">>, <<"request_payload">>, QoS),
|
|
{ok, <<"404">>} = emqx_client:request(Requester, <<"response_topic">>, <<"request_topic">>, <<"invalid_request">>, QoS),
|
|
ok = emqx_client:disconnect(Responser),
|
|
ok = emqx_client:disconnect(Requester).
|
|
|
|
request_response(_Config) ->
|
|
request_response_per_qos(?QOS_2),
|
|
request_response_per_qos(?QOS_1),
|
|
request_response_per_qos(?QOS_0),
|
|
request_response_exception(?QOS_0),
|
|
request_response_exception(?QOS_1),
|
|
request_response_exception(?QOS_2).
|
|
|
|
share_sub_request_topic(_Config) ->
|
|
share_sub_request_topic_per_qos(?QOS_2),
|
|
share_sub_request_topic_per_qos(?QOS_1),
|
|
share_sub_request_topic_per_qos(?QOS_0).
|
|
|
|
share_sub_request_topic_per_qos(QoS) ->
|
|
application:set_env(?APPLICATION, shared_subscription_strategy, random),
|
|
ReqTopic = <<"request-topic">>,
|
|
RspTopic = <<"response-topic">>,
|
|
Group = <<"g1">>,
|
|
Properties = #{ 'Request-Response-Information' => 1},
|
|
Opts = fun(ClientId) -> [{proto_ver, v5},
|
|
{client_id, atom_to_binary(ClientId, utf8)},
|
|
{properties, Properties}
|
|
] end,
|
|
{ok, Requester} = emqx_client:start_link(Opts(requester)),
|
|
{ok, _} = emqx_client:connect(Requester),
|
|
|
|
{ok, Responser1} = emqx_client:start_link([{request_handler, fun(Req) -> <<"1-", Req/binary>> end} | Opts(requester1)]),
|
|
{ok, _} = emqx_client:connect(Responser1),
|
|
|
|
{ok, Responser2} = emqx_client:start_link([{request_handler, fun(Req) -> <<"2-", Req/binary>> end} | Opts(requester2)]),
|
|
{ok, _} = emqx_client:connect(Responser2),
|
|
|
|
ok = emqx_client:sub_request_topic(Responser1, QoS, ReqTopic, Group),
|
|
ok = emqx_client:sub_request_topic(Responser2, QoS, ReqTopic, Group),
|
|
%% Send a request, wait for response, validate response then return responser ID
|
|
ReqFun = fun(Req) ->
|
|
{ok, Rsp} = emqx_client:request(Requester, RspTopic, ReqTopic, Req, QoS),
|
|
case Rsp of
|
|
<<"1-", Req/binary>> -> 1;
|
|
<<"2-", Req/binary>> -> 2
|
|
end
|
|
end,
|
|
Ids = lists:map(fun(I) -> ReqFun(integer_to_binary(I)) end, lists:seq(1, 100)),
|
|
%% we are testing with random shared-dispatch strategy,
|
|
%% fail if not all responsers got a chance to handle requests
|
|
?assertEqual([1, 2], lists:usort(Ids)),
|
|
ok = emqx_client:disconnect(Responser1),
|
|
ok = emqx_client:disconnect(Responser2),
|
|
ok = emqx_client:disconnect(Requester).
|
|
|
|
receive_messages(Count) ->
|
|
receive_messages(Count, []).
|
|
|
|
receive_messages(0, Msgs) ->
|
|
Msgs;
|
|
receive_messages(Count, Msgs) ->
|
|
receive
|
|
{publish, Msg} ->
|
|
receive_messages(Count-1, [Msg|Msgs]);
|
|
_Other ->
|
|
receive_messages(Count, Msgs)
|
|
after 10 ->
|
|
Msgs
|
|
end.
|
|
|
|
basic_test(_Config) ->
|
|
Topic = nth(1, ?TOPICS),
|
|
ct:print("Basic test starting"),
|
|
{ok, C} = emqx_client:start_link(),
|
|
{ok, _} = emqx_client:connect(C),
|
|
|
|
{ok, _, [2]} = emqx_client:subscribe(C, Topic, qos2),
|
|
{ok, _} = emqx_client:publish(C, Topic, <<"qos 2">>, 2),
|
|
{ok, _} = emqx_client:publish(C, Topic, <<"qos 2">>, 2),
|
|
{ok, _} = emqx_client:publish(C, Topic, <<"qos 2">>, 2),
|
|
?assertEqual(3, length(receive_messages(3))),
|
|
ok = emqx_client:disconnect(C).
|
|
|
|
will_message_test(_Config) ->
|
|
{ok, C1} = emqx_client:start_link([{clean_start, true},
|
|
{will_topic, nth(3, ?TOPICS)},
|
|
{will_payload, <<"client disconnected">>},
|
|
{keepalive, 2}]),
|
|
{ok, _} = emqx_client:connect(C1),
|
|
|
|
{ok, C2} = emqx_client:start_link(),
|
|
{ok, _} = emqx_client:connect(C2),
|
|
|
|
{ok, _, [2]} = emqx_client:subscribe(C2, nth(3, ?TOPICS), 2),
|
|
timer:sleep(10),
|
|
ok = emqx_client:stop(C1),
|
|
timer:sleep(5),
|
|
?assertEqual(1, length(receive_messages(1))),
|
|
ok = emqx_client:disconnect(C2),
|
|
ct:print("Will message test succeeded").
|
|
|
|
offline_message_queueing_test(_) ->
|
|
{ok, C1} = emqx_client:start_link([{clean_start, false},
|
|
{client_id, <<"c1">>}]),
|
|
{ok, _} = emqx_client:connect(C1),
|
|
|
|
{ok, _, [2]} = emqx_client:subscribe(C1, nth(6, ?WILD_TOPICS), 2),
|
|
ok = emqx_client:disconnect(C1),
|
|
{ok, C2} = emqx_client:start_link([{clean_start, true},
|
|
{client_id, <<"c2">>}]),
|
|
{ok, _} = emqx_client:connect(C2),
|
|
|
|
ok = emqx_client:publish(C2, nth(2, ?TOPICS), <<"qos 0">>, 0),
|
|
{ok, _} = emqx_client:publish(C2, nth(3, ?TOPICS), <<"qos 1">>, 1),
|
|
{ok, _} = emqx_client:publish(C2, nth(4, ?TOPICS), <<"qos 2">>, 2),
|
|
timer:sleep(10),
|
|
emqx_client:disconnect(C2),
|
|
{ok, C3} = emqx_client:start_link([{clean_start, false},
|
|
{client_id, <<"c1">>}]),
|
|
{ok, _} = emqx_client:connect(C3),
|
|
|
|
timer:sleep(10),
|
|
emqx_client:disconnect(C3),
|
|
?assertEqual(3, length(receive_messages(3))).
|
|
|
|
overlapping_subscriptions_test(_) ->
|
|
{ok, C} = emqx_client:start_link([]),
|
|
{ok, _} = emqx_client:connect(C),
|
|
|
|
{ok, _, [2, 1]} = emqx_client:subscribe(C, [{nth(7, ?WILD_TOPICS), 2},
|
|
{nth(1, ?WILD_TOPICS), 1}]),
|
|
timer:sleep(10),
|
|
{ok, _} = emqx_client:publish(C, nth(4, ?TOPICS), <<"overlapping topic filters">>, 2),
|
|
timer:sleep(10),
|
|
|
|
Num = length(receive_messages(2)),
|
|
?assert(lists:member(Num, [1, 2])),
|
|
if
|
|
Num == 1 ->
|
|
ct:print("This server is publishing one message for all
|
|
matching overlapping subscriptions, not one for each.");
|
|
Num == 2 ->
|
|
ct:print("This server is publishing one message per each
|
|
matching overlapping subscription.");
|
|
true -> ok
|
|
end,
|
|
emqx_client:disconnect(C).
|
|
|
|
%% keepalive_test(_) ->
|
|
%% ct:print("Keepalive test starting"),
|
|
%% {ok, C1, _} = emqx_client:start_link([{clean_start, true},
|
|
%% {keepalive, 5},
|
|
%% {will_flag, true},
|
|
%% {will_topic, nth(5, ?TOPICS)},
|
|
%% %% {will_qos, 2},
|
|
%% {will_payload, <<"keepalive expiry">>}]),
|
|
%% ok = emqx_client:pause(C1),
|
|
%% {ok, C2, _} = emqx_client:start_link([{clean_start, true},
|
|
%% {keepalive, 0}]),
|
|
%% {ok, _, [2]} = emqx_client:subscribe(C2, nth(5, ?TOPICS), 2),
|
|
%% ok = emqx_client:disconnect(C2),
|
|
%% ?assertEqual(1, length(receive_messages(1))),
|
|
%% ct:print("Keepalive test succeeded").
|
|
|
|
redelivery_on_reconnect_test(_) ->
|
|
ct:print("Redelivery on reconnect test starting"),
|
|
{ok, C1} = emqx_client:start_link([{clean_start, false},
|
|
{client_id, <<"c">>}]),
|
|
{ok, _} = emqx_client:connect(C1),
|
|
|
|
{ok, _, [2]} = emqx_client:subscribe(C1, nth(7, ?WILD_TOPICS), 2),
|
|
timer:sleep(10),
|
|
ok = emqx_client:pause(C1),
|
|
{ok, _} = emqx_client:publish(C1, nth(2, ?TOPICS), <<>>,
|
|
[{qos, 1}, {retain, false}]),
|
|
{ok, _} = emqx_client:publish(C1, nth(4, ?TOPICS), <<>>,
|
|
[{qos, 2}, {retain, false}]),
|
|
timer:sleep(10),
|
|
ok = emqx_client:disconnect(C1),
|
|
?assertEqual(0, length(receive_messages(2))),
|
|
{ok, C2} = emqx_client:start_link([{clean_start, false},
|
|
{client_id, <<"c">>}]),
|
|
{ok, _} = emqx_client:connect(C2),
|
|
|
|
timer:sleep(10),
|
|
ok = emqx_client:disconnect(C2),
|
|
?assertEqual(2, length(receive_messages(2))).
|
|
|
|
%% subscribe_failure_test(_) ->
|
|
%% ct:print("Subscribe failure test starting"),
|
|
%% {ok, C, _} = emqx_client:start_link([]),
|
|
%% {ok, _, [2]} = emqx_client:subscribe(C, <<"$SYS/#">>, 2),
|
|
%% timer:sleep(10),
|
|
%% ct:print("Subscribe failure test succeeded").
|
|
|
|
dollar_topics_test(_) ->
|
|
ct:print("$ topics test starting"),
|
|
{ok, C} = emqx_client:start_link([{clean_start, true},
|
|
{keepalive, 0}]),
|
|
{ok, _} = emqx_client:connect(C),
|
|
|
|
{ok, _, [1]} = emqx_client:subscribe(C, nth(6, ?WILD_TOPICS), 1),
|
|
{ok, _} = emqx_client:publish(C, << <<"$">>/binary, (nth(2, ?TOPICS))/binary>>,
|
|
<<"test">>, [{qos, 1}, {retain, false}]),
|
|
timer:sleep(10),
|
|
?assertEqual(0, length(receive_messages(1))),
|
|
ok = emqx_client:disconnect(C),
|
|
ct:print("$ topics test succeeded").
|